/*
 * Licensed to the Apache Software Foundation (ASF) under one
 * or more contributor license agreements.  See the NOTICE file
 * distributed with this work for additional information
 * regarding copyright ownership.  The ASF licenses this file
 * to you under the Apache License, Version 2.0 (the
 * "License"); you may not use this file except in compliance
 * with the License.  You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing,
 * software distributed under the License is distributed on an
 * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 * KIND, either express or implied.  See the License for the
 * specific language governing permissions and limitations
 * under the License.
 */
package org.apache.shiro.spring.config

import org.apache.shiro.SecurityUtils
import org.apache.shiro.authc.UsernamePasswordToken
import org.apache.shiro.authz.ModularRealmAuthorizer
import org.apache.shiro.event.EventBus
import org.apache.shiro.mgt.DefaultSecurityManager
import org.apache.shiro.mgt.SecurityManager
import org.apache.shiro.realm.text.TextConfigurationRealm
import org.apache.shiro.spring.testconfig.RealmTestConfiguration
import org.apache.shiro.spring.web.ShiroFilterFactoryBean
import org.apache.shiro.spring.web.config.ShiroWebConfiguration
import org.apache.shiro.spring.web.config.ShiroWebFilterConfiguration
import org.apache.shiro.subject.Subject
import org.junit.jupiter.api.Test
import org.junit.jupiter.api.extension.ExtendWith
import org.springframework.aop.framework.Advised
import org.springframework.beans.factory.annotation.Autowired
import org.springframework.test.context.junit.jupiter.SpringExtension
import org.springframework.test.context.junit.jupiter.SpringJUnitConfig

import static org.hamcrest.MatcherAssert.assertThat
import static org.hamcrest.Matchers.*
import static org.junit.jupiter.api.Assertions.*

/**
 * @since 1.4.0
 */
@SpringJUnitConfig(classes = [RealmTestConfiguration, ShiroConfiguration, ShiroWebConfiguration, ShiroWebFilterConfiguration])
@ExtendWith(SpringExtension.class)
class ShiroWebConfigurationTest {

    @Autowired
    private SecurityManager securityManager

    @Autowired
    private EventBus eventBus;

    @Autowired
    private ShiroFilterFactoryBean shiroFilterFactoryBean

    @Test
    public void testMinimalConfiguration() {

        // first do a quick check of the injected objects
        assertNotNull securityManager
        assertThat securityManager.realms, hasSize(1)
        assertThat securityManager.realms, hasItem(instanceOf(TextConfigurationRealm))
        assertNull securityManager.cacheManager

        assertNotNull shiroFilterFactoryBean
        assertThat shiroFilterFactoryBean.filters, anEmptyMap()

        assertSame(((Advised) SecurityUtils.unwrapSecurityManager(securityManager, DefaultSecurityManager).getEventBus())
                .getTargetSource().getTarget(), eventBus)

        def defaultSecurityManager = (DefaultSecurityManager) securityManager
        def authorizer = (ModularRealmAuthorizer) defaultSecurityManager.getAuthorizer();
        assertNull authorizer.rolePermissionResolver
        assertNull authorizer.permissionResolver

        // now lets do a couple quick permission tests to make sure everything has been initialized correctly.
        Subject joeCoder = new Subject.Builder(securityManager).buildSubject()
        joeCoder.login(new UsernamePasswordToken("joe.coder", "password"))
        joeCoder.checkPermission("read")
        assertTrue joeCoder.hasRole("user")
        assertFalse joeCoder.hasRole("admin")
        joeCoder.logout()
    }

}
